Transmit 5では現在開いているローカルもしくはリモートのSFTPディレクトリをすばやくターミナルで開く、ターミナルで開く機能が搭載されました。

• サーバとの接続がパスワード認証の場合、ターミナルで接続する際にも改めてパスワードを尋ねるダイアログが表示されます。
• 鍵認証で、あらかじめ ~/.ssh/config ファイルに記述されている場合、ターミナルで接続する際にもその設定が使用されます。より詳しい情報として、ライブラリ PanicアプリでSSH鍵を使用するもご参照ください。

注意: 現時点では、ターミナルで開く機能と、TransmitやPanic Syncに格納されている認証鍵との間で互換性はありません。

はじめに

デフォルトでは、Transmitは下記のAppleScriptを利用してmacOSに標準搭載されているターミナル.appを起動します:

on openTerminal(location, remoteHost, serverPort)
	
	tell application "Terminal"
		activate
		
		set targetTab to ""
		set sshCommand to ""

		if ((count of remoteHost) is greater than 0) then
			set cdCommand to " 'cd \"" & location & "\"; eval \"$SHELL -il\"'"
			set sshCommand to "ssh -t " & "'" & remoteHost & "'"
		else
			set cdCommand to "cd \"" & location & "\""
		end if

		if (serverPort is greater than 0) then
			set sshCommand to sshCommand & " -p " & serverPort
		end if

		if ((count of location) is greater than 0) then
			set sshCommand to sshCommand & cdCommand
		end if

		if (window 1 exists) and (window 1 is visible) and not (selected tab of window 1 is busy) then
			set targetTab to selected tab of window 1
			
			if ((count of sshCommand) is greater than 0) then
				do script sshCommand in targetTab
			end if
			
		else
			
			if ((count of sshCommand) is greater than 0) then
				set targetTab to do script sshCommand
			end if
			
		end if
		
	end tell
	
end openTerminal

スクリプトをカスタマイズする

Transmitに搭載されたこの ターミナルで開く 機能を実行した際、その振る舞いをカスタマイズ — 例えば、お気に入りのターミナルエミュレータを使用したり、他のコマンドを実行させたり — することが可能です。

カスタマイズするには、まず新規ファイルを作成します:

$ touch ~/Scripts/TransmitOpenTerminal.txt

次に、上のデフォルトのスクリプトをコピーし、新規ファイルにペーストします。そして必要なカスタマイズを行なってください。

そして、下記のコマンドを実行してあなたのカスタマイズされたスクリプトをセットします:

$ defaults write com.panic.Transmit OpenTerminalScriptPath ~/Scripts/TransmitOpenTerminal.txt

次回以降、ツールバーのターミナルで開くボタンや、移動 > ターミナルで開くをメニューで選択すると、あなたの準備したカスタムスクリプトが実行されるようになります。